Parent page: Using GUI Forms in TestComplete

Even though automation scripts are intended to drive the application under test there are cases when communication with tester is required. With TestComplete, we have a vast arsenal of predefined GUI controls for that (and those, acquainted with Delphi, will be pleasantly surprised by the way it’s organized).

Today’s post provides an example of creating and using dialog with custom event handlers – whenever script user provides input, event handler may be used to provide a customized response.
In the scope of the exercise let’s use the following task.

• Setup form prompts to choose an environment where test plan is to be run
• User can choose one of predefined environments: DEV, SIT, UAT
• Receives a response as a url of the environment
• User can leave suggested by default test data file or can type filepath directly

Preparing Modal Form

We begin with a sample form.

Add Edit Controls, Buttons, and Labels

Set Object Properties

Form

• Name – object name to use in the code; ‘Security’ in my example
• Caption – title of the window when the form is displayed

Label controls

• Caption – displayed text

Edit Box Control

• Name – object name to use in the code; ‘ShowUrl’ in my example
• Text - initial value
• ReadOnly = True – because user can’t input Url directly

Combo Box Control

• Name – object name to use in the code; ‘Environment’/’TestData’ in my example
• Properties.Items – items to select; ‘DEV’, ‘SIT’, ‘UAT’ in my example
• ItemIndex = 0 – initial selection
• Properties.DropDownListStyle = lsFixedList – for Environment combobox
• Properties.DropDownListStyle = lsEditList – for TestData combobox

Buttons

• Caption – displayed text; ‘OK’/’Cancel’ in my example
• Cancel = True – for ‘Cancel’ button
• ModalResult = mrCancel – for ‘Cancel’ button
• Default = True – for ‘OK’ button
• ModalResult = mrOK – for ‘OK’ button

Set Event Handler

Properties

Path

Code

Public Sub Setup_Environment_OnChange(Sender)
  Dim sEnvironment

  sEnvironment = UserForms.Setup.Environment.Text

  Select Case sEnvironment
    Case "DEV"
      UserForms.Setup.ShowUrl.Text = "http://dev/"
      UserForms.Setup.TestData.Text = "W:\Test Suite\Data\DEV.xlsx"
    Case "SIT"
      UserForms.Setup.ShowUrl.Text = "http://sit/"
      UserForms.Setup.TestData.Text = "W:\Test Suite\Data\SIT.xlsx"
    Case "UAT"
      UserForms.Setup.ShowUrl.Text = "http://uat/"
      UserForms.Setup.TestData.Text = "W:\Test Suite\Data\UAT.xlsx"
  End Select

End Sub

Example

Public Function Form1()
  Dim objDlg
  Dim sEnvironment, sTestData
  Dim Result

  'Get object's instance
  Set objDlg = UserForms.Setup

  'Execute
  Result = objDlg.ShowModal

  If Result = mrOK Then
    'retrieve the selected input
    sEnvironment = objDlg.Environment.Text
    sTestData = objDlg.TestData.Text
  Else
    'Respond
    MsgBox "Execution cancelled", vbOKOnly
    'exit function or finalize execution
  End If

End Function

Parent page: Using GUI Forms in TestComplete

Even though automation scripts are intended to drive the application under test there are cases when communication with tester is required. With TestComplete, we have a vast arsenal of predefined GUI controls for that (and those, acquainted with Delphi, will be pleasantly surprised by the way it’s organized).

Today’s post provides an example of creating and using ‘Username/Password’ dialog.
But, first, a couple of words why automation scripts would need one.

No, this is not an authorization to run the scripts. This is for the scripts.
Maybe you need to connect to the database. Or run the scripts with administrator’s permission. Or it’s just a security requirement from your stakeholders.

Whatever it is, you better not store such sensitive data in a file or the source code. Make them exist only during run-time.

Preparing Modal Form

We begin with a sample form.

Add Edit Controls, Buttons, and Labels

Set Object Properties

Form

• Name – object name to use in the code; ‘Security’ in my example
• Caption – title of the window when the form is displayed

Label controls

• Caption – displayed text

Edit Box Controls

• Name – object name to use in the code; ‘EditUsername’/'EditPassword’ in my example
• EditPassword.Properties.EchoMode = eemPassword – to mask password characters

Buttons

• Caption – displayed text; ‘OK’/'Cancel’ in my example
• Cancel = True – for ‘Cancel’ button
• ModalResult = mrCancel - for ‘Cancel’ button
• Default = True – for ‘OK’ button
• ModalResult = mrOK - for ‘OK’ button

Example

  Dim objDlg
  Dim sUsername, sPassword
  Dim Result

  'Get object's instance
  Set objDlg = UserForms.Security

  'Execute
  Result = objDlg.ShowModal

  If Result = mrOK Then
    'retrieve the input
    sUsername = objDlg.EditUsername.Text
    sPassword = objDlg.EditPassword.Text
  Else
    'Respond
    MsgBox "Execution cancelled", vbOKOnly
    'exit function or finalize execution
  End If

Parent page: Using GUI Forms in TestComplete

Even though automation scripts are intended to drive the application under test there are cases when communication with tester is required. With TestComplete, we have a vast arsenal of predefined GUI controls for that (and those, acquainted with Delphi, will be pleasantly surprised by the way it’s organized).

The second post in the series provides an example of using ‘File Open’ dialog.

We begin with a sample form.

Add ‘TOpenDialog’ Icon

Set Dialog Properties

The property names are straight-forward, so I cover only main ones.

• Name – object name to use in the code;
• InitialDir – folder to begin browsing from;
• Filter – to specify what filetypes to display;
• FileName – will contain the full pathname of the file upon successful selection;
• Options\ofPathMustExist – set True if selection accepts only existing files;
• Options\ofFileMustExist - set True if selection accepts only existing files;

These properties can be set in the Property Editor or directly in the code at run-time as in the example below.

Example

'Get object's instance
Set objDlg = UserForms.PlanOpenDlg
'Assign path
objDlg.OpenDialog.InitialDir = "C:\FakePath\Test Plans"
'Set filter
objDlg.OpenDialog.Filter = "XML Test Plans (*.xml)|*.XML"
'Execute as modal and get the status
If objDlg.OpenDialog.Execute Then
  'retrieve the selected file
  sTestPlan = objDlg.OpenDialog.FileName
Else
  'Respond
  MsgBox "Execution cancelled", vbOKOnly
  'exit function or finalize execution
End If

Parent page: Using GUI Forms in TestComplete

Even though automation scripts are intended to drive the application under test there are cases when communication with tester is required. With TestComplete, we have a vast arsenal of predefined GUI controls for that (and those, acquainted with Delphi, will be pleasantly surprised by the way it’s organized).

Today’s post walks through the main preparation steps.

Add New Project Item

Select Project Item Type – ‘User Forms’

Add New Item into ‘User Forms’

Add New Item into ‘User Forms’ – Create a New Form

You end up in the Form Editor

Note that you can add GUI controls from 4 main categories:

• ‘Editors’
• ‘Helpers’
• ‘Extra’
• ‘Dialogs’
• ‘Buttons’

Parent page: Service Functions – String (QTP, VBScript)

Description

Get token string from the source string. Position is relative, defined by another token-keyword and a number.

Implementation

Public Function GetTokenByKeyword(ByVal strSource, ByVal chrDelimiter, ByVal strKeyword, ByVal intNumber, ByRef strToken)
	Dim Tokens, intCount, intIndex
	Dim i, boolRC

	Tokens = Split(strSource, chrDelimiter)
	intCount = UBound(Tokens)+1
	intIndex = -1

	For i=0 To intCount-1
		If Regex_Test(Tokens(i),strKeyword) Then
			intIndex = i
			Exit For
		End If
	Next

	If intIndex = -1 Then
    strToken = ""
		GetTokenByKeyword = False
		Exit Function
	End If

	If (intIndex+1+intNumber) > intCount Then
    strToken = ""
		GetTokenByKeyword = False
		Exit Function
	End If

	If (intIndex+1+intNumber) < 0 Then
    strToken = ""
		GetTokenByKeyword = True
		Exit Function
	End If

	strToken = Tokens(intIndex+intNumber)
	GetTokenByKeyword = True
End Function

Parent page: Service Functions – String (QTP, VBScript)

Description

Get token string from the source string. Position is absolute, defined by number.

Implementation

Public Function GetTokenByNumber(ByVal strSource, ByVal chrDelimiter, ByVal intNumber, ByRef strToken)
	Dim Tokens, intCount

	strSource = ReplaceEx(strSource, "  *", " ", False)
	Tokens = Split(strSource, chrDelimiter)
	intCount = UBound(Tokens)

	If  intNumber > intCount Then
		GetTokenByNumber = FALSE
		Exit Function
	End If

	strToken = Tokens(intNumber-1)
	GetTokenByNumber = TRUE
End Function

Parent page: Service Functions – MSXMLDOM (QTP, TestComplete, VBScript)

Description

Copy all child elements (and attributes, comments, text nodes) from one XML node to another.

Implementation

Public Function CopyChildElements(ByRef objXMLSrc, ByRef objXMLDest)
   Dim objCloneNode
 
   If objXMLSrc is Nothing Then
    Set MoveChildElements = objXMLDest
    Exit Function
   End If

   If objXMLDest is Nothing Then
    Set objXMLDest = objXMLSrc.CloneNode(True)
    Set CopyChildElements = objXMLDest
    Exit Function
   End If

   Set objCloneNode = objXMLSrc.CloneNode(True)

   While Not (objCloneNode.FirstChild is Nothing)
    Call objXMLDest.AppendChild(objCloneNode.FirstChild)
   Wend

   Set objCloneNode = Nothing

   Set CopyChildElements = objXMLDest

End Function

Test Code

  Set objXMLDoc = CreateXMLDOM("test")
  Set objXMLParent = CreateChildElementByName(objXMLDoc.DocumentElement, "Modules", "modules parent node")
  If objXMLParent is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 1")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 2")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 3")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If

  sText = "<root>text</root>"
  Set objXMLDoc2 = CreateXMLDOMFromString(sText)
  If objXMLDoc2 is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateXMLDOMFromString", "")
  End If

  Set objXMLParent2 = Nothing
  Set objXMLParent2 = CopyChildElements(objXMLParent, objXMLParent2)

  Set objXMLNode = ChildElementByName(objXMLParent2, "Macro") 
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.BaseName <> "Macro" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.Text <> "macro node 1" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  Set objXMLNode = ChildElementByName(objXMLParent, "Macro") 
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.BaseName <> "Macro" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.Text <> "macro node 1" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If

  Set objXMLParent2 = CreateChildElementByName(objXMLDoc2.DocumentElement, "Modules", "modules parent node dest")
  If objXMLParent2 is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLParent2 = CopyChildElements(objXMLParent, objXMLParent2)
  Set objXMLNode = ChildElementByName(objXMLParent2, "Macro") 
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.BaseName <> "Macro" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.Text <> "macro node 1" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  Set objXMLNode = ChildElementByName(objXMLParent, "Macro") 
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.BaseName <> "Macro" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.Text <> "macro node 1" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If

Parent page: Service Functions – MSXMLDOM (QTP, TestComplete, VBScript)

Description

Move all child elements (and attributes, comments, text nodes) from one XML node to another. 

Implementation

Public Function MoveChildElements(ByRef objXMLSrc, ByRef objXMLDest)

   If objXMLSrc is Nothing Then
    Set MoveChildElements = objXMLDest
    Exit Function
   End If

   If objXMLDest is Nothing Then
    Set objXMLDest = objXMLSrc.CloneNode(False)
   End If

   While Not (objXMLSrc.FirstChild is Nothing)
    Call objXMLDest.AppendChild(objXMLSrc.FirstChild)
   Wend

   Set MoveChildElements = objXMLDest

End Function

Test Code

  Set objXMLDoc = CreateXMLDOM("test")
  Set objXMLParent = CreateChildElementByName(objXMLDoc.DocumentElement, "Modules", "modules parent node")
  If objXMLParent is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 1")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 2")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 3")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If

  sText = "<root>text</root>"
  Set objXMLDoc2 = CreateXMLDOMFromString(sText)
  If objXMLDoc2 is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateXMLDOMFromString", "")
  End If
  Set objXMLParent2 = CreateChildElementByName(objXMLDoc2.DocumentElement, "Modules", "modules parent node dest")
  If objXMLParent2 is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If

  Set objXMLParent2 = MoveChildElements(objXMLParent, objXMLParent2)

  Set objXMLNode = ChildElementByName(objXMLParent2, "Macro") 
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.BaseName <> "Macro" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.Text <> "macro node 1" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If

  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 1")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 2")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If
  Set objXMLNode = CreateChildElementByName(objXMLParent, "Macro", "macro node 3")
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "CreateChildElementByName", "")
  End If

  Set objXMLParent2 = Nothing
  Set objXMLParent2 = MoveChildElements(objXMLParent, objXMLParent2)

  Set objXMLNode = ChildElementByName(objXMLParent2, "Macro") 
  If objXMLNode is Nothing Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.BaseName <> "Macro" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If
  If objXMLNode.Text <> "macro node 1" Then
    Call Reporter.ReportEvent(micFail, "ChildElementByName", "")
  End If

Description 

Get object reference. Get total number of items in the list. Generate an index within the given range. Select item by index.

Implementation

Dim objPage, objList
Dim boolRC
Dim intItemsCount, intRndItem

'Assumptions:
' "Google Advanced Search" page is up
' "Results per page" WebList exists and enabled

'Get page object
Set objPage = Browser("CreationTime:=0").Page("title:=Google Advanced Search")
boolRC = objPage.Exist(0)
If Not boolRC Then
 ExitTest
End If

'Get list object
Set objList = objPage.WebList("name:=num")
boolRC = objList.Exist(0)
If Not boolRC Then
 ExitTest
End If

'Get number of list items
intItemsCount = objList.GetROProperty("items count")
'Create random index
Randomize
intRndItem = CInt(Rnd*intItemsCount)
'Select the item
'Note: selection by index is zero-based
objList.Select "#" & intRndItem

Parent page: Service Functions – MSXMLDOM (QTP, TestComplete, VBScript)

Description

Locate XML node depth within the hierarchy. Valid argument: an XML element node (NODE_ELEMENT type). 

Implementation

Public Function XMLElementDepth(ByRef objXMLElement)
   Dim intDepth
   Dim objXMLNode

  If objXMLElement is Nothing Then
  XMLElementDepth = -1
  Exit Function
 End If

 'NODE_DOCUMENT(9)
 If objXMLElement.NodeType = 9 Then
  XMLElementDepth = 0
  Exit Function
 End If

 'NODE_ELEMENT(1)
 If objXMLElement.NodeType <> 1 Then
  XMLElementDepth = -1
  Exit Function
 End If

 intDepth = 0
 Set objXMLNode = objXMLElement
 Do While True
  Set objXMLNode = objXMLNode.parentNode
  intDepth = intDepth + 1
  If objXMLNode.NodeType = 9 Then
   Exit Do
  End If
 Loop

 XMLElementDepth = intDepth

End Function