Reference page: Service Functions – System (QTP, VBScript)

Description 

Check folder exists – check folder has files. Iterate through collection of files and keep reference of the most recently modified file (its DateLastModified property is always the highest number). The remaining reference is the one that you need. In case of errors the function returns Nothing. 

Note. In some cases, you may want to use DateCreated or DateLastAccessed properties.

Implementation

Public Function GetLastModifiedFile(ByVal sFolderPath)
  Dim FSO, objFolder, objFile
  Dim objFileResult, longDateTime
  Dim boolRC
 
  Set FSO = CreateObject("Scripting.FileSystemObject")
  boolRC = FSO.FolderExists(sFolderPath)
  If Not boolRC Then
    Set FSO = Nothing
    Set GetLastModifiedFile = Nothing
    Exit Function
  End If

  Set objFolder = FSO.GetFolder(sFolderPath)
  If objFolder.Files.Count = 0 Then
    Set FSO = Nothing
    Set objFolder = Nothing
    Set GetLastModifiedFile = Nothing
    Exit Function
  End If
 
  Set objFileResult = Nothing
  longDateTime = CDate(0)
 
  For Each objFile in objFolder.Files
 
    If objFile.DateLastModified > longDateTime Then
      Set objFileResult = objFile
      longDateTime = objFile.DateLastModified
    End If
   
  Next
 
  Set FSO = Nothing
  Set objFolder = Nothing
  Set GetLastModifiedFile = objFileResult

End Function

In the previous post I warned about possible synchronization issues while copying a complex and/or large file-folder structure. To ensure reliability of the operation performed we may verify the structure that was created.

We need to answer the following questions before designing the script.

• Which folders and files should it verify?
• Which way should it verify specified object?
• Where this information is stored?
• What is the format of data provided?

For this example, we make the following assumptions.

• A file named “folders.txt” is stored in the root folder of a template and automatically copied with it while creating a user folder.
• The file is in raw text format
• Only folders are specified

Assuming that we use sample structure from the previous example as a baseline, “folders.txt” file will contain the following lines.

Application Data\Application1
Application Data\Application2
Application Data\Application1\INI
Documents
Documents\Back-up

Order of the folders specified is not important.

CheckFolderStructure function provided below performs a sequential checking.

Public Function CheckFolderStructure(ByVal sTargetFolder)
Dim boolRC
Dim sCheckFile, objCheckFile
Dim sCheckLine, sCheckPath

Set objFSO = CreateObject("Scripting.FileSystemObject")

boolRC = objFSO.FolderExists(sTargetFolder)
If Not boolRC Then
    Set objFSO = Nothing
    CheckFolderStructure = False
    Exit Function
End If

sCheckFile = sTargetFolder & "\folders.txt"
boolRC = objFSO.FileExists(sCheckFile)
If Not boolRC Then
    Set objFSO = Nothing
    CheckFolderStructure = False
    Exit Function
End If

Set objCheckFile = objFSO.OpenTextFile(sCheckFile, 1)

Do While (Not objCheckFile.AtEndOfStream)
    sCheckLine = objCheckFile.ReadLine()
    sCheckPath = sTargetFolder & "\" & sCheckLine
    boolRC = objFSO.FolderExists(sCheckPath)
    If Not boolRC Then
        objCheckFile.Close
        Set objCheckFile = Nothing
        Set objFSO = Nothing
        CheckFolderStructure = False
        Exit Function
    End If
Loop

objCheckFile.Close
Set objCheckFile = Nothing
Set objFSO = Nothing
CheckFolderStructure = True

End Function

How to create a complex folder structure by using a template

In the previous post I provided code example that creates a folder and then applies security permissions on it. However, as per requirements, user folders often come with a predefined structure of folders and some files created by default. Sure, we can write script that creates folders one by one. But will it be a compact and maintainable solution?

Let’s try an alternative way.

We will use the following template as an example.

Root folder (will become user’s personal folder): “testuser”
Pre-defined user folders: “Application Data”, “Documents”
Files coming by default: “Application Data\readme.txt”, “Documents\readme.txt”

'Declare external function
'It will be used to pause execution during asynchronous calls
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
'
Dim sTemplateFolder, sUserFolder
sTemplateFolder = "C:\Temp\Users\testuser"
sUserFolder = "C:\Temp\Users\DoeJohn"
           
'Create folder - through XCOPY
sCommandLine = "c:\windows\system32\XCOPY.EXE """ & sTemplateFolder & """ & " """ & sUserFolder & """ /E /I /H /K /O"
intRC = Shell(sCommandLine, vbHide)
'Shell is an asynchronous call - system needs time to process it
'Sync
Sleep XCOPY_THINK_TIME
       
'Error-handling
If boolRC Then
'code your recovery steps
End If

XCOPY Tool

The Tool. XCopy is a Microsoft’s tool that comes with an operating system. Using the link provided you can learn more about it.

The Path. In the example provided the path is hard-coded. You can also make it configurable/customizable.

Command line. The following command line switches were used.

/E – Copy entire subdirectory structure, including empty ones.
/I – To specify that destination objects must be created (otherwise, the tool asks for a confirmation).
/H – Copy files with “hidden” and “system” attributes (the tool skips them by default).
/K – Retain “read-only” attribute on destination files if presented on the source files.
/O – Copy files/folders with security permissions as on the source files.

Synchronization

XCOPY_THINK_TIME must be defined considering the following factors: total size of a template structure, caching, network speed, and priority of your process. Worth to try copying a few times through command line manually to define a sufficient time for a delay.

If your template has a very complex structure or big in size you should check consistency of the created structure to ensure reliability of the automatic process.

In this post  I provide code snippets for SetACL tool command line automation.  Examples of command line instructions were taken from here.

The code presented below is written in VBA for MS Excel.
CreateUserFolder function can create folders on a local or network drive. After user folder is created, the function sets typical access permissions by calling SetACL tool through command line interface (by using Shell function of Excel/VBA).
Pass-in parameters
sUserFolder – full path to the target folder
sLogin – user account name (login name)

'Declare external function
'It will be used to pause execution during asynchronous calls
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
'
'
'Main function
Public Function CreateUserFolder(ByVal sUserFolder, ByVal sLogin)
Dim boolRC, intRC
Dim objFSO, objUserFolder
Dim sToolPath, sCommandLine

'We assume that SetACL is stored at the same location as our Excel file
sToolPath = Workbooks.Item(1).Path & "\SetACL.exe"

Set objFSO = CreateObject("Scripting.FileSystemObject")

'Create user folder
On Error Resume Next
    Set objUserFolder = objFSO.CreateFolder(sUserFolder)
    boolRC = (Err.Number <> 0)
On Error GoTo 0
Set objFSO = Nothing

'Error-handling
If boolRC Then
   CreateUserFolder = False
   Exit Function
End If
   
'Sync
Sleep 250
   
'Remove inheritance
sCommandLine = """" & sToolPath & """ -on """ & sUserFolder & """ -ot file -actn setprot -op ""dacl:p_c;sacl:p_c"""
intRC = Shell(sCommandLine, vbHide)
'Shell is asynchronous call - system needs time to process it
'Sync
Sleep 1000
   
'Limited error-handling
If intRC = 0 Then
   CreateUserFolder = False
   Exit Function
End If
   
'Remove "Users"/"Domain Users" groups
sCommandLine = """" & sToolPath & """ -on """ & sUserFolder  & """ -ot file -actn trustee "
sCommandLine = sCommandLine & "-trst ""n1:users;ta:remtrst;w:dacl"" "
sCommandLine = sCommandLine & "-actn trustee -trst ""n1:domain users;ta:remtrst;w:dacl"""
intRC = Shell(sCommandLine, vbHide)
'Shell is an asynchronous call - system needs time to process it
'Sync
Sleep 1000
   
'Limited error-handling
If intRC = 0 Then
   CreateUserFolder = False
   Exit Function
End If
   
'Add Modify user permissions
sCommandLine = """" & sToolPath & """ -on """ & sUserFolder  & """ -ot file -actn ace "
sCommandLine = sCommandLine & "-ace ""n:" & sLogin & ";p:change"""
intRC = Shell(sCommandLine, vbHide)
'Shell is an asynchronous call - system needs time to process it
'Sync
Sleep 1000
   
'Limited error-handling
If intRC = 0 Then
   CreateUserFolder = False
   Exit Function
End If
   
'Deny Delete Folder user permissions
sCommandLine = """" & sToolPath & """ -on """ & sUserFolder & """ -ot file -actn ace "
sCommandLine = sCommandLine & "-ace ""n:" & sLogin & ";p:delete;i:np;m:deny;w:dacl"""
intRC = Shell(sCommandLine, vbHide)
'Shell is an asynchronous call - system needs time to process it
'Sync
Sleep 1000
   
'Limited error-handling
If intRC = 0 Then
   CreateUserFolder = False
   Exit Function
End If
   
CreateUserFolder = True

End Function

Reference page: Service Functions – System (QTP, VBScript)

Question

The question was asked here.

I need to check number of text files in the folder but i dont know names

Answer

Checking what number of files is contained in a folder is simple. More challenging tasks would be processing files based on type or name patterns.

Implementation

1. Retrieve total number of files 

Dim sParentFolder

sParentFolder = "C:\TEMP"

Set FSO = CreateObject("Scripting.FileSystemObject")
boolRC = FSO.FolderExists(sParentFolder)
Set FSO = Nothing 'release an object
If Not boolRC Then
'do what you need to do if
'folder does not exist
End If

Set objParentFolder = FSO.GetFolder(sParentFolder)

Set objFilesColl = objParentFolder.Files

'objFilesColl.Count contains total number of files

2. Count files based on extension 

Used resources: Service Functions – String (QTP, VBScript)

In the second example number of text files is just counted. Excel files’ names are stored in Dictionary object for further processing.

Dim sFolder
Dim FSO, objFolder, objFile, objXLSList
Dim intTXTCount

sFolder = "C:\TEMP"

Set FSO = CreateObject("Scripting.FileSystemObject")
Set objXLSList = CreateObject("Scripting.Dictionary")

Set objFolder = FSO.GetFolder(sFolder)
intTXTCount = 0
For Each objFile In objFolder.Files
 If Regex_Test(objFile.Name, ".*\.[t,T][t,T][t,T]") Then
  intTXTCount = intTXTCount + 1
 End If
 If Regex_Test(objFile.Name, ".*\.[x,X][l,L][s,S]") Then
  objXLSList.Add objXLSList.Count, objFile.Name
 End If
Next

Parent page: Service Functions – System (QTP, VBScript)

Use FileSystemObject.FolderExists method.
Argument should be a full path string.

 
When to use it? Always before trying to access the folder (delete, rename, or read from) or create files in it.

Note. Always release the object you created when you no longer need it. If you don’t do that then in the long run it’ll cause you memory leakage problem.

Set FSO = CreateObject("Scripting.FileSystemObject")
boolRC = FSO.FolderExists(sFolderName)
Set FSO = Nothing 'release an object
If Not boolRC Then
'do what you need to do if
'folder does not exist
End If

How to create a unique subfolder

Description

A subfolder is created based on the name pattern and a date-time stamp, e.g. “AccountSearch 2009-10-14 17-18-03″.  You can add extra steps and form the code as a function that returns full path of the newly created subfolder.

sName – name pattern

sFullPath - full path of the newly created subfolder

Dim date_now, dd, dt
Dim FSO
Dim sFullPath

date_now = Now

dd = Year(date_now) & "-" & AlignNumber(Month(date_now), 2, "0") & "-" & AlignNumber(Day(date_now), 2, "0")
dt = AlignNumber(Hour(date_now), 2, "0") & "-" & AlignNumber(Minute(date_now), 2, "0") & "-" & AlignNumber(Second(date_now), 2, "0")

If sName = "" Then
sSubfolder = "Data"&" " & dd & " " & dt
Else
sSubfolder = sName & " " & dd & " " & dt
End If
sFullPath = sLogPath & "\" & sSubfolder & "\"

Set FSO = CreateObject("Scripting.FileSystemObject")
FSO.CreateFolder(sFullPath)
Set FSO = Nothing

How to duplicate an existing file

(If you want to access the file but it’s locked)

Description

sFileName – name of the file to duplicate
sNewName – name of created file (generated automatically), pass-back argument.

Uses UniqueFilename function to generate a name for the duplicate file.

Public Function DuplicateFile(ByVal sFileName, ByRef sNewName)
Dim boolRC
Dim FSO, objFile
Dim sName, sPath
Set FSO = CreateObject("Scripting.FileSystemObject")

'Verify source file exists
boolRC = FSO.FileExists(sFileName)
If Not boolRC Then
Set FSO = Nothing
DuplicateFile = FALSE
Exit Function
End If

'Separate filename and filepath
Set objFile = FSO.GetFile(sFileName)
sName = objFile.Name
sPath = objFile.Path
sPath = Left(sPath, Len(sPath)-Len(sName))
Set objFile = Nothing

'Generate unique name for the dup file
sNewName = sPath & "\" _
_ & UniqueFilename(sName, sPath, AssociateParameters("prefix = dup, index = 100"))

'Copy file
FSO.CopyFile sFileName, sNewName

Set FSO = Nothing
DuplicateFile = TRUE
End Function

How to generate a unique file name
if the file name already exists in the given folder

(That often happens, if you need to create a series of files or duplicate an existing file)

Description

sFileName – the “original” file name or file name template
sFolderName – parent folder (full path required)
objParameter – Dictionary object containing optional parameters.

• Prefix. If you want the file name to be preceded with some text (e.g. copy_userdata.xls) define a prefix.
• Index. If you want to define starting number in the series (e.g. userdata_100.xls) use index.

Note. The function does not generate a file. It generates a file name!

Example. Duplicate an existing file

Public Function UniqueFilename(ByVal sFileName, ByVal sFolderName, ByVal objParameter)

Dim FSO, boolRC, sTypeName
Dim index,prefix
Dim sNewName, BaseName, Extension

Set FSO = CreateObject("Scripting.FileSystemObject")
'to check if the objParameter passed is a dictionary object
sTypeName = TypeName (objParameter)
If sTypeName <> "Dictionary" Then
Set objParameter = CreateObject("Scripting.Dictionary")
End If

'retrieving and defaulting the parameters from objParameter
prefix = objParameter.item("prefix")
If prefix <> "" Then prefix = prefix & "_"

index = objParameter.item("index")
If Not IsNumeric(index) Then index = 1

'Separate filename and extension
BaseName = FSO.GetBaseName(sFileName)
Extension = FSO.GetExtensionName(sFileName)

'Generate filename and verify it doesn't exist

Do
sNewName = prefix & BaseName & "_" & Cstr(index) & "." & Extension
boolRC = FSO.FileExists(sFolderName & "\" & sNewName)
index = index+1
Loop Until boolRC = FALSE

Set FSO = Nothing
UniqueFilename = sNewName
End Function

Parent page: Service Functions – System (QTP, VBScript)

Use FileSystemObject.GetFile method to obtain a File object.
Argument should be a full path string.

Set FSO = CreateObject(“Scripting.FileSystemObject”)

Check if the file exists first.

When to use it? There is a variety of utility tasks related to it: get parent folder, create another file in the same folder, create another file with the same name, etc.

Does file format matter? No. It could be text file, excel spreadsheet, bitmap, binary file, – anything. Just make sure you pass into both filename and extension.

Note. Always release the object you created when you no longer need it. If you don’t do that in the long run it’ll cause you memory leakage problem.

sFileName = "C:\TEMP\Log145473.txt"

Set objFile = FSO.GetFile(sFileName)
sName = objFile.Name
sPath = objFile.Path
sPath = Left(sPath, Len(sPath)-Len(sName))
Set objFile = Nothing
Set FSO = Nothing

'sName contains "Log145473.txt"
'sPath contains "C:\TEMP\"