Reference page: Service Functions – System (QTP, VBScript)

Description 

Check folder exists – check folder has files. Iterate through collection of files and keep reference of the most recently modified file (its DateLastModified property is always the highest number). The remaining reference is the one that you need. In case of errors the function returns Nothing. 

Note. In some cases, you may want to use DateCreated or DateLastAccessed properties.

Implementation

Public Function GetLastModifiedFile(ByVal sFolderPath)
  Dim FSO, objFolder, objFile
  Dim objFileResult, longDateTime
  Dim boolRC
 
  Set FSO = CreateObject("Scripting.FileSystemObject")
  boolRC = FSO.FolderExists(sFolderPath)
  If Not boolRC Then
    Set FSO = Nothing
    Set GetLastModifiedFile = Nothing
    Exit Function
  End If

  Set objFolder = FSO.GetFolder(sFolderPath)
  If objFolder.Files.Count = 0 Then
    Set FSO = Nothing
    Set objFolder = Nothing
    Set GetLastModifiedFile = Nothing
    Exit Function
  End If
 
  Set objFileResult = Nothing
  longDateTime = CDate(0)
 
  For Each objFile in objFolder.Files
 
    If objFile.DateLastModified > longDateTime Then
      Set objFileResult = objFile
      longDateTime = objFile.DateLastModified
    End If
   
  Next
 
  Set FSO = Nothing
  Set objFolder = Nothing
  Set GetLastModifiedFile = objFileResult

End Function

Close/Terminate Specified Process

Parent page: Service Functions – DotNetFactory (QTP, VBScript)

Description

Create an instance of Process object through DotNetFactory – search for local processes by name – iterate through the returned array and close one by one.

First attempt – “gentle” close (via CloseMainWindow()). WaitForExit() gives a process some time to finalize, you may customize the timeout. If didn’t work – force close and unload (via Kill()).

Note. Name is case-insensitive but no wildcards supported.

The function returns “True” if no specified processes found remaining.

Errors/exceptions might be thrown if your account’s privileges do not allow closing the process (you can first  try doing this via TaskManager to see if you are allowed). You can also wrap external calls in On Error statement.

Implementation

Public Function SysProcessKill(ByVal sName)
 Dim objSDPMain, objSDP
 Dim objSDPArr
 Dim boolRC
 Dim Iter
 
 Set objSDPMain = DotNetFactory.CreateInstance("System.Diagnostics.Process", "System")
 Set objSDPArr = objSDPMain.GetProcessesByName(sName)

 ' Trying to close first
 For Iter=0 To objSDPArr.length-1
  Set objSDP = objSDPArr.GetValue(CInt(Iter))
  objSDP.CloseMainWindow()
  objSDP.WaitForExit(CInt(5000))
 Next

 Set objSDPArr = objSDPMain.GetProcessesByName(sName)

 'If anything is still left, trying to terminate
 For Iter=0 To objSDPArr.length-1
  Set objSDP = objSDPArr.GetValue(CInt(Iter))
  objSDP.Kill()
  objSDP.WaitForExit(CInt(5000))
 Next

 'Checking if something is still in memory
 Set objSDPArr = objSDPMain.GetProcessesByName(sName)
 boolRC = CInt(objSDPArr.length) = 0

 Set objSDP = Nothing
 Set objSDPArr = Nothing
 Set objSDPMain = Nothing

 SysProcessKill = boolRC

End Function

Examples

boolBanished = True
 boolRC = SysProcessExists("iexplore")
 If boolRC Then
  boolGhostProcess = True
  boolBanished = boolBanished AND SysProcessKill("iexplore")
 End If

Check If a Process Exists in Memory

Parent page: Service Functions – DotNetFactory (QTP, VBScript)

Description

Create an instance of Process object through DotNetFactory – search for local processes by name – return result as boolean.

Note. Name is case-insensitive but no wildcards supported.

Implementation

Public Function SysProcessExists(ByVal sName)
 Dim objSDP
 Dim objSDPArr
 Dim boolRC
 
 Set objSDP = DotNetFactory.CreateInstance("System.Diagnostics.Process", "System")
 Set objSDPArr = objSDP.GetProcessesByName(sName)

 boolRC = CInt(objSDPArr.length) > 0

 Set objSDP = Nothing
 Set objSDPArr = Nothing

 SysProcessExists = boolRC

End Function

Examples

Dim boolRCboolRC = SysProcessExists("winword")
if boolRC Then
  MsgBox("WinWord is running")
End If

Parent page: GUI Recognition with TestComplete

TestComplete provides a whole set of run-time GUI recognition functionalities, based, however, on the same approach: recognition by property values and/or location of the object in internal hierarchy. In addition to methods that immediately return a child object, if it’s available, there are others, that help finding objects that only about to appear – and this way you can create parameterized and flexible synchronization points.

Today’s post is an example of using custom recognition / synchronization function

Let’s start with the example. If you want to execute the code, make sure you also copied custom function FindChildSync provided in the second section.

 
  Dim boolRC
  Dim IEProcess, IExplore
  Dim PropNames, PropValues
  Dim Page1, Page2
  Dim objLink

  'Close browser
  PropNames = Array("processname", "index")
  PropValues = Array("iexplore", 1)
  Set IEProcess = Sys.FindChild(PropNames, PropValues, 1, True)
  If IEProcess.Exists then
    IEProcess.Close(10000)
  End if 

  'Open browser and navigate to the web-site 
  Set IExplore = TestedApps.iexplore
  IExplore.Params.SimpleParams.CommandLineParameters = "http://www.google.ca/"
  Call IExplore.Run(1, False, 5000) 

  'Find First Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", <a href="http://www.google.ca/">http://www.google.ca/</a>)
  Set Page1 = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  If Not Page1.Exists then
    Exit Sub
  End if

  'Find Second Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/advanced_search?hl=en")
  Set Page2 = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  boolRC = Page2.Exists 'Returns False
  'Find Web Link Object
  PropNames = Array("tagName", "namePropStr")
  PropValues = Array("A", "advanced_search*")
  Set objLink = Page1.FindChild(PropNames, PropValues, 10, True)

  If Not objLink.Exists then
    Exit Sub
  End if

  objLink.Click
 
  boolRC = Page2.Exists 'Returns False

  'Find Web Page by specific object name
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/advanced_search?hl=en")
  Set Page2 = FindChildSync(Sys.Process("iexplore"), PropNames, PropValues, 1, 10)
  boolRC = Page2.Exists 'Returns true

At the very end, line #50 (I highlighted it for you), you can see call to a custom function. Unlike WaitChild built-in method in TestComplete, it uses description properties to identify an object.

Below you can find description and source code of the function.

FindChildSync

Description

Validate and initialize passed in parameters. – Start timer. – Begin identification loop.
Use FindChild standard method to attempt locating child GUI element. Repeat attempts until object is found or timeout is reached.

Returns GUI object’s reference or Nothing – if search wasn’t successful.

Implementation

Public Function FindChildSync(ByRef objGUIParent, ByRef PropNames, ByRef PropValues, ByVal intDepth, ByVal intSyncMax)
  Dim intStopWatch
  Dim objGUIElement
 
  'Init
  If objGUIParent is Nothing Then
    Set FindChildSync = Nothing
    Exit Function
  End If

  If Not objGUIParent.Exists Then
    Set FindChildSync = Nothing
    Exit Function
  End If
 
  If (Not isArray(PropNames)) OR (Not isArray(PropValues)) Then
    Set FindChildSync = Nothing
    Exit Function
  End If

  If Not isNumeric(intDepth) Then intDepth = 0
  If intDepth < 0 Then intDepth = 0
 
  'Set timer
  If intSyncMax < 0 Then intSyncMax = 0
  intStopWatch = Time()

  'Loop until child object appeared or timeout reached
  Do While True

    On Error Resume Next
      Set objGUIElement = objGUIParent.FindChild(PropNames, PropValues, intDepth, True)
    On Error GoTo 0
 
    If objGUIElement.Exists Then
      'Object's found
      Exit Do
    Else
      'Keep trying
    End If

    'Exit by timeout
   If DateDiff("s", intStopWatch, Time()) > intSyncMax Then
      Set FindChildSync = Nothing
      Exit Function
   End If
   
  Loop
 
  Set FindChildSync = objGUIElement
 
End Function

Parent page: GUI Recognition with TestComplete

TestComplete provides a whole set of run-time GUI recognition functionalities, based, however, on the same approach: recognition by property values and/or location of the object in internal hierarchy. In addition to methods that immediately return a child object, if it’s available, there are others, that help finding objects that only about to appear – and this way you can create parameterized and flexible synchronization points.

Today’s post is about WaitChild method

Let’s start with the example.

  Dim boolRC
  Dim IEProcess, IExplore
  Dim PropNames, PropValues, arrComboBox
  Dim Page1, Page2
  Dim objForm, objLink, objComboBox

  'Close browser
  PropNames = Array("processname", "index")
  PropValues = Array("iexplore", 1)
  Set IEProcess = Sys.FindChild(PropNames, PropValues, 1, True)
  If IEProcess.Exists then
    IEProcess.Close(10000)
  End if 

  'Open browser and navigate to the web-site 
  Set IExplore = TestedApps.iexplore
  IExplore.Params.SimpleParams.CommandLineParameters = "http://www.google.ca/"
  Call IExplore.Run(1, False, 5000) 

  'Find First Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/")
  Set Page1 = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  If Not Page1.Exists then
    Exit Sub
  End if

  'Find Second Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/advanced_search?hl=en")
  Set Page2 = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  boolRC = Page2.Exists 'Returns False
  'Find Web Link Object
  PropNames = Array("tagName", "namePropStr")
  PropValues = Array("A", "advanced_search*")
  Set objLink = Page1.FindChild(PropNames, PropValues, 10, True)

  If Not objLink.Exists then
    Exit Sub
  End if

  objLink.Click
 
  boolRC = Page2.Exists 'Returns False

  'Find Web Page by specific object name
  Set Page2 = Sys.Process("iexplore").WaitChild("Page(""http://www.google.ca/advanced_search?hl=en"")", 1000)
  boolRC = Page2.Exists 'Returns true

  'Find Web Page by generic object name
  Set Page2 = Sys.Process("iexplore").WaitChild("Page*", 1000)
  boolRC = Page2.Exists 'Returns true

We agreed that idly waiting for hard-coded amount of time is inflexible and unreliable synchronization approach. Luckily, we can let TestComplete to wait while checking if the object has appeared.

Note the line 47.  We do not supply property name / property value recognition properties but Page2 will be successfully found. That’s because WaitChild method simply accepts object’s name. You can find it out through the Object Properties Viewer.

That means, however, that we have to know it ahead of time; to inspect each GUI object at least once while creating test scripts. And what if another, unexpected page will appear instead?

To address such issues, implement flexible, 2-step synchronization process. First, wait for a page to appear (see line 51). Then try to identify it, using description properties, to find out if that is the page you expected.

You can also build your own, custom recognition / synchronization function, and we will talk about that in the next post in this series.

Parent page: GUI Recognition with TestComplete

First of all, a short note to those readers who like to rush into conclusions.
This post is about a feature, not bug.

Here I continue exploring TestComplete GUI recognition capabilities with code example. The previous two posts (here and here) were about Find, FindChild, and FindAllChildren methods. Today I want to show the case when these methods appear not working, find out why it’s valid, and how to properly work it out.

Let’s start with the code example.

  Dim boolRC
  Dim IEProcess, IExplore
  Dim PropNames, PropValues, arrComboBox
  Dim Page1, Page2
  Dim objForm, objLink, objComboBox
  '

  'Close browser
  PropNames = Array("processname", "index")
  PropValues = Array("iexplore", 1)
  Set IEProcess = Sys.FindChild(PropNames, PropValues, 1, True)
  If IEProcess.Exists then
    IEProcess.Close(10000)
  End if 
  '

  'Open browser and navigate to the web-site 
  Set IExplore = TestedApps.iexplore
  IExplore.Params.SimpleParams.CommandLineParameters = "http://www.google.ca/"
  Call IExplore.Run(1, False, 5000) 
  '

  'Find First Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/")
  Set Page1 = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  If Not Page1.Exists then
    Exit Sub
  End if
  '

  'Find Second Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/advanced_search?hl=en")
  Set Page2 = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  boolRC = Page2.Exists 'Returns False
  '
  'Find Web Link Object
  PropNames = Array("tagName", "namePropStr")
  PropValues = Array("A", "advanced_search*")
  Set objLink = Page1.FindChild(PropNames, PropValues, 10, True)

  If Not objLink.Exists then
    Exit Sub
  End if

  objLink.Click
 
  aqUtils.Delay 2000
 
  boolRC = Page2.Exists 'Still returns False
  '

  'Find Second Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/advanced_search?hl=en")
  Set Page2 = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  boolRC = Page2.Exists 'Finally, Returns True
  'See explanation why below

First of all, note the line 49 (it’s highlighted). aqUtils.Delay 2000 statement there is a primitive synchronization point: we give the web browser 2 seconds to reload the page by making the script idle for that amount of time. Not the best way for a properly created automation, but we will talk about synchronization in the subsequent posts.

Second, note line 51. While the Web Page (“Advanced Search”) surely exists on the screen at that point of time during execution, .Exists returns False. That is critically important!

With Find/FindChild methods you can not map GUI objects if they are not available.

The explanation is simple though. If a parent object does not have a child with description properties matching the specified set, it has nothing to return. The object, that is still returned is just a “stub” object which has only .Exists property which is always False. For identification of objects which about to appear TestComplete has another family of methods – WaitChild, WaitNamedChild, and other. We will try them in the next post.

Parent page: GUI Recognition with TestComplete

TestComplete provides a whole set of run-time GUI recognition functionalities, based, however, on the same approach: recognition by property values and/or location of the object in internal hierarchy.

Today’s post is about FindAllChildren method

If proper selection of GUI recognition properties is challenge number zero for a beginner automation engineer, the real first one would be recognition of objects without unique set of recognition properties.  As I mentioned, one possible way is to go up (from the object’s stand point) the hierarchy and identify parent or grand parent object that has a unique description. Although it sometimes helps, we may still have a family of objects corresponding to the same recognition properties. In some cases, that is enough, and we can simply retrieve them all in array by using FindAllChildren method (see line 57 in the code example below).

Note, that if no single object were found the returned array is empty (UBound gives -1).

  Dim IEProcess, IExplore
  Dim PropNames, PropValues, arrComboBox
  Dim Page
  Dim objForm, objLink, objComboBox

  'Close browser
  PropNames = Array("processname", "index")
  PropValues = Array("iexplore", 1)
  Set IEProcess = Sys.FindChild(PropNames, PropValues, 1, True)
  If IEProcess.Exists then
    IEProcess.Close(10000)
  End if 

  'Open browser and navigate to the web-site 
  Set IExplore = TestedApps.iexplore
  IExplore.Params.SimpleParams.CommandLineParameters = "http://www.google.ca/"
  Call IExplore.Run(1, False, 5000) 

  'Find Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/")
  Set Page = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  If Not Page.Exists then
    Exit Sub
  End if

  'Find Web Link Object
  PropNames = Array("tagName", "namePropStr")
  PropValues = Array("A", "advanced_search*")
  Set objLink = Page.FindChild(PropNames, PropValues, 10, True)

  If Not objLink.Exists then
    Exit Sub
  End if

  objLink.Click
 
  'Re-identify Web Page
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/advanced_search?hl=en")
  Set Page = Page.Find(PropNames, PropValues, 1, True)
  If Not Page.Exists then
    Exit Sub
  End if

  'Get Web Form Object
  PropNames = Array("objecttype", "outerText")
  PropValues = Array("Form", "Find web pages*")
  Set objForm = Page.FindChild(PropNames, PropValues, 5, True)
  If Not objForm.Exists then
    Exit Sub
  End if
 
  'Get Child Objects of specified type
  PropNames = Array("tagName")
  PropValues = Array("SELECT")
  arrComboBox = objForm.FindAllChildren(PropNames, PropValues, 10, True)
 
  'Retrieve object by index
  Set objComboBox = arrComboBox(6) 

  objComboBox.ClickItem("20 results")

Parent page: GUI Recognition with TestComplete

TestComplete provides a whole set of run-time GUI recognition functionalities, based, however, on the same approach: recognition by property values and/or location of the object in internal hierarchy.

Today’s post is about Find method

We continue with example from the previous post.

What happened when the script clicked on the link? – Web page is reloaded; it’s a new object now.
Before we can operate it, we need to identify it first.

We can go down the hierarchy again starting from Sys or Process objects, but we may re-identify the page using Find method, as in the example below.

  Dim IEProcess, IExplore
  Dim PropNames, PropValues
  Dim Page
  Dim objLink

  'Close browser
  PropNames = Array("processname", "index")
  PropValues = Array("iexplore", 1)
  Set IEProcess = Sys.FindChild(PropNames, PropValues, 1, True)
  If IEProcess.Exists then
    IEProcess.Close(10000)
  End if 

  'Open browser and navigate to the web-site 
  Set IExplore = TestedApps.iexplore
  IExplore.Params.SimpleParams.CommandLineParameters = "http://www.google.ca/"
  Call IExplore.Run(1, False, 5000) 

  'Find Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/")
  Set Page = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  If Not Page.Exists then
    Exit Sub
  End if

  'Find Web Link Object
  PropNames = Array("tagName", "namePropStr")
  PropValues = Array("A", "advanced_search*")
  Set objLink = Page.FindChild(PropNames, PropValues, 10, True)

  If Not objLink.Exists then
    Exit Sub
  End if

  objLink.Click
  
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/advanced_search?hl=en")
  Set Page = Page.Find(PropNames, PropValues, 1, True)
  If Not Page.Exists then
    Exit Sub
  End if

Parent page: GUI Recognition with TestComplete

TestComplete provides a whole set of run-time GUI recognition functionalities, based, however, on the same approach: recognition by property values and/or location of the object in internal hierarchy.

Today’s post is about FindChild method

Let’s start with the example.

  Dim IEProcess, IExplore
  Dim PropNames, PropValues
  Dim Page
  Dim objLink
  'Close browser window

  PropNames = Array("processname", "index")
  PropValues = Array("iexplore", 1)
  Set IEProcess = Sys.FindChild(PropNames, PropValues, 1, True)
  If IEProcess.Exists then
    IEProcess.Close(10000)
  End if 
 
  'Open browser and navigate to the web-site
  Set IExplore = TestedApps.iexplore
  IExplore.Params.SimpleParams.CommandLineParameters = "http://www.google.ca/"
  Call IExplore.Run(1, False, 5000) 

  'Find Web Page Object
  PropNames = Array("objecttype", "url")
  PropValues = Array("page", "http://www.google.ca/")
  Set Page = Sys.Process("iexplore").FindChild(PropNames, PropValues, 1, True)
  If Not Page.Exists then
    Exit Sub
  End if

  'Find Web Link Object
  PropNames = Array("tagName", "namePropStr")
  PropValues = Array("A", "advanced_search*")
  Set objLink = Page.FindChild(PropNames, PropValues, 4, True)

  If Not objLink.Exists then
    Exit Sub
  End if

  'Click on the link
  objLink.Click

Note highlighted lines: this is where object recognition properties are defined. As you see from lines ## 7,8, TestComplete supports not only GUI objects recognition, but recognition of any object in hierarchy, including processes.

The third parameter of FindChild method is depth, which is defined by position of the object in hierarchy.  In our example, the full path string to the link from the root is:

Sys.Process(“iexplore”).Page(“http://www.google.ca/”).Form(“f”).Table(0).Cell(0, 2).Link(0)

Which means, counting from the Sys object, depth of the link is 6. Counting from the Page object, the depth is 4.

Note, that we specify max depth to search within. An object could be found “higher” in the hierarchy; but if it’s “lower” than the depth specified, then search won’t be successful.

If an object has unique identification properties in wide context, middle step may be omitted, as in the example below.

  Dim IEProcess, IExplore
  Dim PropNames, PropValues
  Dim objLink
  'Close browser window

  PropNames = Array("processname", "index")
  PropValues = Array("iexplore", 1)
  Set IEProcess = Sys.FindChild(PropNames, PropValues, 1, True)
  If IEProcess.Exists then
    IEProcess.Close(10000)
  End if 
 

  'Open browser and navigate to the web-site

  Set IExplore = TestedApps.iexplore
  IExplore.Params.SimpleParams.CommandLineParameters = "http://www.google.ca/"
  Call IExplore.Run(1, False, 5000) 

  'Find Web Link Object

  PropNames = Array("tagName", "namePropStr")
  PropValues = Array("A", "advanced_search*")
  Set objLink = Sys.Process("iexplore").FindChild(PropNames, PropValues, 10, True)

  If Not objLink.Exists then
    Exit Sub
  End if

  objLink.Click

 “I don’t even see the code anymore;
all I see now is blonde, brunette, redhead”,
Cypher (Matrix the Movie)

Parent page: GUI Recognition with TestComplete

Unlike operators from the popular movie, automation engineer sees picture first, but has a need to get inside down to the code.
In TestComplete we can do that with Object Properties Wizard which retrieves both static data (like DOM details) and run-time GUI object properties.

In the picture above, Object Properties dialog displayed properties of Google logo panel, which contains image and text. The table goes over a hundred entries which can be overwhelming at first. However, some properties can not be used in GUI recognition, some other won’t help to identify object in a unique fashion. 

For Web GUI, the most important recognition properties are the following.

• HTML ID (named “idStr” in TestComplete). A unique-per-page value, but not a mandatory HTML attribute.
• HTML Tag (tagName). Non-unique but mandatory.
• A text within HTML Tag (innerText). Non-unique and not mandatory.
• Floating hint text (Title). Non-unique and not mandatory.

Generally, if you don’t have a single property that allows uniquely identifying GUI object, you should compile a combination of properties which allows that.

Examples.

• If idStr is not empty use only this property.
• Use combination of tagName and innerText, or combination of tagName and Title.

But what if such combination simply doesn’t exist?

Well, that makes it a little harder. We need to go up the hierarchy and identify parent or grand parent object that has a unique description. Once parent is retrieved, we may reconsider our description properties for the child. For instance, there could be multiple links across the web page, but only one within the particular table.

There are other, more complex GUI recognition challenges, that automation engineers must master – as testing begins from observation.